[arch-commits] Commit in kauth/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, March 9, 2019 @ 09:53:08
  Author: arojas
Revision: 347478

archrelease: copy trunk to testing-x86_64

Added:
  kauth/repos/testing-x86_64/
  kauth/repos/testing-x86_64/PKGBUILD
    (from rev 347477, kauth/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: kauth/repos/testing-x86_64/PKGBUILD (from rev 347477, kauth/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-03-09 09:53:08 UTC (rev 347478)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kauth
+pkgver=5.56.0
+pkgrel=1
+pkgdesc='Abstraction to system policy and authentication features'
+arch=(x86_64)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(kcoreaddons polkit-qt5)
+makedepends=(extra-cmake-modules qt5-tools clang python-pyqt5 doxygen sip)
+optdepends=('python-pyqt5: for the Python bindings')
+groups=(kf5)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('cbcca13064b112dff26d1f78b1e77c8ad263cb663aab6329bc6e0a6505f4613d'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-$pkgver
+# Install dbus conf in /usr/share 
+  sed -e 's|${SYSCONF_INSTALL_DIR}/dbus-1/system.d|${CMAKE_INSTALL_DBUSDIR}/system.d|g' -i src/ConfigureChecks.cmake -i cmake/KF5AuthMacros.cmake
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}