[arch-commits] Commit in lxtask/repos (2 files)

[Balló György]

    Date: Saturday, March 9, 2019 @ 17:10:50
  Author: bgyorgy
Revision: 438514

archrelease: copy trunk to community-testing-x86_64

Added:
  lxtask/repos/community-testing-x86_64/
  lxtask/repos/community-testing-x86_64/PKGBUILD
    (from rev 438513, lxtask/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: lxtask/repos/community-testing-x86_64/PKGBUILD (from rev 438513, lxtask/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-03-09 17:10:50 UTC (rev 438514)
@@ -0,0 +1,53 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at koon.fr>
+
+pkgbase=lxtask
+pkgname=(lxtask lxtask-gtk3)
+pkgver=0.1.9
+pkgrel=1
+pkgdesc='Task manager of the LXDE Desktop'
+arch=('x86_64')
+license=('GPL2')
+url='https://lxde.org/'
+depends=('gtk2' 'gtk3')
+makedepends=('intltool')
+source=(https://downloads.sourceforge.net/lxde/$pkgbase-$pkgver.tar.xz)
+sha256sums=('41ea88f0adf31a840e4b9d137ca5ea802860d1a117845ba25f3080d74a876433')
+
+build() {
+  # GTK+ 2 version
+  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
+  cd gtk2
+  ./configure --sysconfdir=/etc --prefix=/usr
+  make
+
+  cd "$srcdir"
+  # GTK+ 3 version
+  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
+  cd gtk3
+  ./configure --sysconfdir=/etc --prefix=/usr --enable-gtk3
+  make
+}
+
+package_lxtask() {
+  groups=('lxde')
+  depends=('gtk2')
+
+  cd gtk2
+  make DESTDIR="$pkgdir" install
+}
+
+package_lxtask-gtk3() {
+  groups=('lxde-gtk3')
+  pkgdesc+=' (GTK+ 3 version)'
+  depends=('gtk3')
+  conflicts=('lxtask')
+
+  cd gtk3
+  make DESTDIR="$pkgdir" install
+
+  # Ignore package by AppStream to avoid duplicated IDs
+  echo 'X-AppStream-Ignore=true' >> "$pkgdir/usr/share/applications/$pkgbase.desktop"
+}