[arch-commits] Commit in haskell-exceptions/repos (2 files)

[Felix Yan]

    Date: Sunday, March 10, 2019 @ 07:07:40
  Author: felixonmars
Revision: 438947

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-exceptions/repos/community-staging-x86_64/
  haskell-exceptions/repos/community-staging-x86_64/PKGBUILD
    (from rev 438946, haskell-exceptions/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-exceptions/repos/community-staging-x86_64/PKGBUILD (from rev 438946, haskell-exceptions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-10 07:07:40 UTC (rev 438947)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=exceptions
+pkgname=haskell-exceptions
+pkgver=0.10.0
+pkgrel=12
+pkgdesc="Extensible optionally-pure exceptions"
+url="https://github.com/ekmett/exceptions/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-transformers-compat')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('53fd0929bc73c7024842aee880d5f6c7e884926e0d6f667a63d12ea457451d8a3aaa44755ace2dac3258be127189ae0eeb299b6c974ebafd4fa33b5c8622fabd')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e 's/< *2.14/<3/' -e 's/< *2.12/<3/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}