[arch-commits] Commit in (5 files)
Alexander Rødseth
arodseth at archlinux.org
Mon Mar 11 15:48:40 UTC 2019
Date: Monday, March 11, 2019 @ 15:48:40
Author: arodseth
Revision: 439773
Add remacs
Added:
remacs/
remacs/repos/
remacs/repos/community-x86_64/
remacs/trunk/
remacs/trunk/PKGBUILD
----------+
PKGBUILD | 65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
Added: remacs/trunk/PKGBUILD
===================================================================
--- remacs/trunk/PKGBUILD (rev 0)
+++ remacs/trunk/PKGBUILD 2019-03-11 15:48:40 UTC (rev 439773)
@@ -0,0 +1,65 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Chris Nixon <chris.nixon at sigma.me.uk>
+
+pkgname=remacs
+pkgver=0.0.0
+pkgrel=1
+pkgdesc='Emacs with parts of it written in Rust'
+arch=(x86_64)
+url='https://github.com/Wilfred/remacs.git'
+license=(GPL)
+depends=(gnutls gpm)
+makedepends=(cargo clang git rustup setconf)
+source=('git+https://github.com/Wilfred/remacs#commit=dc2ea22ddfa1ba077178ffab')
+sha256sums=('SKIP')
+
+prepare() {
+ cd "$pkgname"
+
+ ./autogen.sh
+
+ # Use full path to remacs and remacsclient
+ setconf etc/remacs.service ExecStart '/usr/bin/remacs --fg-daemon'
+ setconf etc/remacs.service ExecStop '/usr/bin/remacsclient --eval "(kill-emacs)"'
+}
+
+build() {
+ cd "$pkgname"
+
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --libexecdir=/usr/lib \
+ --localstatedir=/var \
+ --mandir=/usr/share/man \
+ --infodir=/usr/share/info \
+ --with-sound=no \
+ --with-modules \
+ --without-xft \
+ --without-gconf \
+ --without-gsettings \
+ --without-cairo \
+ --without-xwidgets \
+ --without-makeinfo \
+ --without-x \
+ --enable-link-time-optimization
+ make
+}
+
+package() {
+ make -C "$pkgname" DESTDIR="$pkgdir" install
+
+ # avoid conflicts with other packages
+ rm "$pkgdir/usr/"{bin/{ctags,etags,ebrowse},share/man/man1/{ctags,etags,ebrowse}.1.gz}
+ mv "$pkgdir/usr/share/man/man1/"{e,re}macs.1.gz
+ mv "$pkgdir/usr/share/man/man1/"{e,re}macsclient.1.gz
+ rm -r "$pkgdir/usr/share/info"
+
+ # skip /var/games, /usr/share/pixmaps and /usr/share/applications
+ rm -rf "$pkgdir/"{var/games,usr/share/{pixmaps,applications}}
+
+ # fix permissions
+ find "$pkgdir"/usr/share/remacs/ -exec chown root:root {} \;
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list