[arch-commits] Commit in hoogle/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Mar 11 19:16:32 UTC 2019


    Date: Monday, March 11, 2019 @ 19:16:31
  Author: felixonmars
Revision: 439843

archrelease: copy trunk to community-staging-x86_64

Added:
  hoogle/repos/community-staging-x86_64/
  hoogle/repos/community-staging-x86_64/PKGBUILD
    (from rev 439842, hoogle/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: hoogle/repos/community-staging-x86_64/PKGBUILD (from rev 439842, hoogle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-11 19:16:31 UTC (rev 439843)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hoogle
+pkgver=5.0.17.5
+pkgrel=14
+pkgdesc="Haskell API Search"
+url="http://www.haskell.org/hoogle/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-cmdargs' 'haskell-conduit'
+         'haskell-conduit-extra' 'haskell-connection' 'haskell-extra' 'haskell-foundation'
+         'haskell-hashable' 'haskell-http-conduit' 'haskell-http-types' 'haskell-js-flot'
+         'haskell-js-jquery' 'haskell-mmap' 'haskell-network' 'haskell-network-uri'
+         'haskell-old-locale' 'haskell-process-extras' 'haskell-resourcet' 'haskell-src-exts'
+         'haskell-storable-tuple' 'haskell-tar' 'haskell-uniplate' 'haskell-utf8-string'
+         'haskell-vector' 'haskell-wai' 'haskell-wai-logger' 'haskell-warp' 'haskell-warp-tls'
+         'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('fc7fac9d66ef9b6b498f18a40fab3979f16ce0245ff75882cbfa467af619082db089b5c986d1fc3ab83c43319cb9f76a2476041c55a054cb42567c730996732a')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list