[arch-commits] Commit in ciano (3 files)

Balló György bgyorgy at archlinux.org
Mon Mar 11 19:20:45 UTC 2019


    Date: Monday, March 11, 2019 @ 19:20:45
  Author: bgyorgy
Revision: 439847

archrelease: copy trunk to community-x86_64

Added:
  ciano/repos/
  ciano/repos/community-x86_64/
  ciano/repos/community-x86_64/PKGBUILD
    (from rev 439846, ciano/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: ciano/repos/community-x86_64/PKGBUILD (from rev 439846, ciano/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2019-03-11 19:20:45 UTC (rev 439847)
@@ -0,0 +1,38 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=ciano
+pkgver=0.2.1
+pkgrel=1
+pkgdesc="Multimedia file converter focused on simplicity"
+arch=(x86_64)
+url="https://robertsanseries.github.io/ciano/"
+license=(GPL3)
+depends=(ffmpeg granite imagemagick)
+makedepends=(git meson vala)
+_commit=ac33219d9474af34890635375b5d6bbaf9f15937  # tags/0.2.1
+source=("git+https://github.com/robertsanseries/ciano#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ciano
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd ciano
+  # Use standard icon names
+  sed -i 's/application-add-symbolic/list-add-symbolic/' src/widgets/DialogConvertFile.vala
+}
+
+build() {
+  arch-meson ciano build
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}


More information about the arch-commits mailing list