[arch-commits] Commit in vte3/repos (2 files)
Jan Steffens
heftig at archlinux.org
Wed Mar 13 22:01:35 UTC 2019
Date: Wednesday, March 13, 2019 @ 22:01:34
Author: heftig
Revision: 347874
archrelease: copy trunk to gnome-unstable-x86_64
Added:
vte3/repos/gnome-unstable-x86_64/
vte3/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 347873, vte3/trunk/PKGBUILD)
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Copied: vte3/repos/gnome-unstable-x86_64/PKGBUILD (from rev 347873, vte3/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2019-03-13 22:01:34 UTC (rev 347874)
@@ -0,0 +1,55 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgbase=vte3
+pkgname=(vte3 vte-common)
+pkgver=0.56.0
+pkgrel=1
+pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
+url="https://wiki.gnome.org/Apps/Terminal/VTE"
+arch=(x86_64)
+license=(LGPL)
+options=(!emptydirs)
+depends=(gtk3 pcre2 gnutls)
+makedepends=(intltool gobject-introspection vala glade git gtk-doc gperf)
+_commit=9328a04c3e57e80889a6252d3df2289e1d8c6ef0 # tags/0.56.0^0
+source=("git+https://gitlab.gnome.org/GNOME/vte.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd vte
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd vte
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd vte
+
+ ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/vte \
+ --localstatedir=/var --disable-static --enable-introspection --enable-glade-catalogue --enable-gtk-doc
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+}
+
+package_vte3(){
+ depends+=(vte-common)
+
+ cd vte
+ make DESTDIR="$pkgdir" install
+
+ rm "$pkgdir"/etc/profile.d/vte.sh
+}
+
+package_vte-common() {
+ pkgdesc="Common files used by vte and vte3"
+ depends=(sh)
+
+ cd vte
+ install -Dm644 src/vte.sh "$pkgdir"/etc/profile.d/vte.sh
+}
More information about the arch-commits
mailing list