[arch-commits] Commit in gdm/repos (3 files)

[Jan Steffens]

    Date: Thursday, March 14, 2019 @ 18:46:55
  Author: heftig
Revision: 348059

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gdm/repos/gnome-unstable-x86_64/
  gdm/repos/gnome-unstable-x86_64/0001-Xsession-Don-t-start-ssh-agent-by-default.patch
    (from rev 348058, gdm/trunk/0001-Xsession-Don-t-start-ssh-agent-by-default.patch)
  gdm/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348058, gdm/trunk/PKGBUILD)

------------------------------------------------------+
 0001-Xsession-Don-t-start-ssh-agent-by-default.patch |   32 ++++++
 PKGBUILD                                             |   89 +++++++++++++++++
 2 files changed, 121 insertions(+)

Copied: gdm/repos/gnome-unstable-x86_64/0001-Xsession-Don-t-start-ssh-agent-by-default.patch (from rev 348058, gdm/trunk/0001-Xsession-Don-t-start-ssh-agent-by-default.patch)
===================================================================
--- gnome-unstable-x86_64/0001-Xsession-Don-t-start-ssh-agent-by-default.patch	                        (rev 0)
+++ gnome-unstable-x86_64/0001-Xsession-Don-t-start-ssh-agent-by-default.patch	2019-03-14 18:46:55 UTC (rev 348059)
@@ -0,0 +1,32 @@
+From 328a315c21ec71e563d00699f0a79186b229270a Mon Sep 17 00:00:00 2001
+Message-Id: <328a315c21ec71e563d00699f0a79186b229270a.1541542184.git.jan.steffens at gmail.com>
+From: "Jan Alexander Steffens (heftig)" <jan.steffens at gmail.com>
+Date: Sat, 20 Jun 2015 17:22:38 +0200
+Subject: [PATCH] Xsession: Don't start ssh-agent by default
+
+---
+ data/Xsession.in | 8 --------
+ 1 file changed, 8 deletions(-)
+
+diff --git a/data/Xsession.in b/data/Xsession.in
+index 9d79558c..ff6d9de0 100755
+--- a/data/Xsession.in
++++ b/data/Xsession.in
+@@ -175,14 +175,6 @@ if [ "x$command" = "xdefault" ] ; then
+   fi
+ fi
+ 
+-# add ssh-agent if found
+-sshagent="`gdmwhich ssh-agent`"
+-if [ -n "$sshagent" ] && [ -x "$sshagent" ] && [ -z "$SSH_AUTH_SOCK" ]; then
+-    command="$sshagent -- $command"
+-elif [ -z "$sshagent" ] ; then
+-    echo "$0: ssh-agent not found!"
+-fi
+-
+ echo "$0: Setup done, will execute: $command"
+ 
+ eval exec $command
+-- 
+2.19.1
+

Copied: gdm/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348058, gdm/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-14 18:46:55 UTC (rev 348059)
@@ -0,0 +1,89 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gdm
+pkgname=(gdm libgdm)
+pkgver=3.32.0+2+g820f90f5
+pkgrel=1
+pkgdesc="Display manager and login screen"
+url="https://wiki.gnome.org/Projects/GDM"
+arch=(x86_64)
+license=(GPL)
+depends=(gnome-shell gnome-session upower xorg-xrdb xorg-server xorg-xhost)
+makedepends=(yelp-tools gobject-introspection git docbook-xsl)
+checkdepends=(check)
+_commit=820f90f5a78b81b2e4610da14627266c2135c8b0  # master
+source=("git+https://gitlab.gnome.org/GNOME/gdm.git#commit=$_commit"
+        0001-Xsession-Don-t-start-ssh-agent-by-default.patch)
+sha256sums=('SKIP'
+            '3412f7da0205409f08a126a1d166b644fe0f1d0444f7cdebdce8e59cea2d672c')
+
+pkgver() {
+  cd gdm
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  mkdir build
+  cd gdm
+  patch -Np1 -i ../0001-Xsession-Don-t-start-ssh-agent-by-default.patch
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd build
+  ../gdm/configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib \
+    with_dbus_sys=/usr/share/dbus-1/system.d \
+    --disable-schemas-compile \
+    --disable-static \
+    --enable-gdm-xsession \
+    --enable-ipv6 \
+    --with-default-pam-config=arch \
+    --with-default-path=/usr/local/bin:/usr/local/sbin:/usr/bin \
+    --without-plymouth \
+    --without-tcp-wrappers
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  make -C build check
+}
+
+package_gdm() {
+  depends+=(libgdm)
+  optdepends=('fprintd: fingerprint authentication')
+  backup=(etc/pam.d/gdm-autologin etc/pam.d/gdm-fingerprint etc/pam.d/gdm-launch-environment
+          etc/pam.d/gdm-password etc/pam.d/gdm-smartcard etc/gdm/custom.conf
+          etc/gdm/Xsession etc/gdm/PostSession/Default etc/gdm/PreSession/Default)
+  groups=(gnome)
+
+  DESTDIR="$pkgdir" make -C build install
+
+  chown -Rc 120:120 "$pkgdir/var/lib/gdm"
+
+  # Unused or created at start
+  rm -r "$pkgdir"/var/{cache,log,run}
+
+  install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/gdm.conf" <<END
+g gdm 120 -
+u gdm 120 "Gnome Display Manager" /var/lib/gdm
+END
+
+### Split libgdm
+  mkdir -p libgdm/{lib,share}
+  mv -t libgdm       "$pkgdir"/usr/include
+  mv -t libgdm/lib   "$pkgdir"/usr/lib/{girepository-1.0,libgdm*,pkgconfig}
+  mv -t libgdm/share "$pkgdir"/usr/share/{gir-1.0,glib-2.0}
+}
+
+package_libgdm() {
+  pkgdesc="GDM support library"
+  depends=(systemd glib2 dconf)
+  mv libgdm "$pkgdir/usr"
+}