[arch-commits] Commit in cheese/repos (2 files)

[Jan Steffens]

    Date: Thursday, March 14, 2019 @ 20:15:33
  Author: heftig
Revision: 348079

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  cheese/repos/gnome-unstable-x86_64/
  cheese/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348078, cheese/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: cheese/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348078, cheese/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-14 20:15:33 UTC (rev 348079)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=cheese
+pkgver=3.32.0+2+g5481726b
+pkgrel=1
+pkgdesc="Take photos and videos with your webcam, with fun graphical effects"
+url="https://wiki.gnome.org/Apps/Cheese"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 gstreamer gst-plugins-bad gst-plugins-base gst-plugins-good clutter-gst clutter-gtk
+         libcanberra librsvg gnome-desktop libgudev dconf)
+makedepends=(intltool gobject-introspection itstool vala gnome-common git appstream-glib
+             gnome-video-effects)
+optdepends=('gnome-video-effects: Camera effects')
+groups=(gnome)
+options=(!emptydirs)
+_commit=5481726b186da7763b6a645ff43aee5ac932e10c  # master
+source=("git+https://gitlab.gnome.org/GNOME/cheese.git#commit=$_commit")
+sha256sums=('SKIP')
+
+# TODO: Consider splitting libcheese
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git tag -f 3.32.0 70cd445781ffa08dff1ddad84ee949fd1476d9aa  # Fixup missing tag
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+      --disable-static --disable-schemas-compile --libexecdir=/usr/lib/cheese \
+      --enable-gtk-doc
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}