[arch-commits] Commit in gsound/repos (2 files)

Jan Steffens heftig at archlinux.org
Thu Mar 14 20:49:59 UTC 2019


    Date: Thursday, March 14, 2019 @ 20:49:58
  Author: heftig
Revision: 348107

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gsound/repos/gnome-unstable-x86_64/
  gsound/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348106, gsound/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: gsound/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348106, gsound/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-14 20:49:58 UTC (rev 348107)
@@ -0,0 +1,41 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gsound
+pkgver=1.0.2
+pkgrel=4
+pkgdesc="Small library for playing system sounds"
+url="https://wiki.gnome.org/Projects/GSound"
+license=('LGPL')
+arch=('x86_64')
+depends=(glib2 libcanberra)
+makedepends=(gobject-introspection vala git gtk-doc autoconf-archive)
+_commit=a86946b494aa32782b3f6334344d07b5c11d5219  # tags/1.0.2^0
+source=("git+https://gitlab.gnome.org/GNOME/gsound.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --enable-gtk-doc \
+    --enable-compile-warnings=yes
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  make -C $pkgname check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list