[arch-commits] Commit in gnome-control-center/repos (2 files)

[Jan Steffens]

    Date: Thursday, March 14, 2019 @ 21:31:38
  Author: heftig
Revision: 348124

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-control-center/repos/gnome-unstable-x86_64/
  gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348123, gnome-control-center/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348123, gnome-control-center/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-14 21:31:38 UTC (rev 348124)
@@ -0,0 +1,55 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-control-center
+pkgver=3.32.0.1+11+g82ca937ec
+pkgrel=1
+pkgdesc="GNOME's main interface to configure various aspects of the desktop"
+url="https://gitlab.gnome.org/GNOME/gnome-control-center"
+license=(GPL2)
+arch=(x86_64)
+depends=(accountsservice cups-pk-helper gnome-bluetooth gnome-desktop
+         gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas gtk3
+         libgtop nm-connection-editor sound-theme-freedesktop upower libpwquality
+         gnome-color-manager smbclient libmm-glib libgnomekbd grilo libibus
+         cheese libgudev bolt udisks2 libhandy gsound)
+makedepends=(docbook-xsl modemmanager git python meson)
+checkdepends=(python-dbusmock python-gobject xorg-server-xvfb)
+optdepends=('system-config-printer: Printer settings'
+            'gnome-user-share: Bluetooth and WebDAV file sharing'
+            'gnome-remote-desktop: screen sharing'
+            'rygel: media sharing'
+            'openssh: remote login')
+groups=(gnome)
+_commit=82ca937ecdb8f1e5dbcc75ae2f9d0dbd77c76830  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-control-center.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_CONTROL_CENTER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git submodule init
+  git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+
+build() {
+  arch-meson $pkgname build -D documentation=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+}