[arch-commits] Commit in haskell-hakyll/repos (2 files)

[Felix Yan]

    Date: Friday, March 15, 2019 @ 07:55:27
  Author: felixonmars
Revision: 441825

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hakyll/repos/community-staging-x86_64/
  haskell-hakyll/repos/community-staging-x86_64/PKGBUILD
    (from rev 441824, haskell-hakyll/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: haskell-hakyll/repos/community-staging-x86_64/PKGBUILD (from rev 441824, haskell-hakyll/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-15 07:55:27 UTC (rev 441825)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hakyll
+pkgname=haskell-hakyll
+pkgver=4.12.5.1
+pkgrel=24
+pkgdesc="A static website compiler library"
+url="http://jaspervdj.be/hakyll"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-cryptohash'
+         'haskell-data-default' 'haskell-file-embed' 'haskell-fsnotify' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-lrucache' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'pandoc' 'pandoc-citeproc' 'haskell-random'
+         'haskell-regex-tdfa' 'haskell-resourcet' 'haskell-scientific' 'haskell-tagsoup'
+         'haskell-time-locale-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-wai' 'haskell-wai-app-static' 'haskell-warp' 'haskell-yaml')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('bc8cc9944229c691fbec6b7e6ea52e8a65bd8cc2093d42bd577e30ded1767370b439d8dc694e9842b300f7c884f851cac6a2a9de2817a961c779b83fb0ee1718')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *2.7/<3/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fcheckexternal -fwatchserver -fpreviewserver -fusepandoc
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "https://github.com/jaspervdj/hakyll/issues/682"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}