[arch-commits] Commit in gnome-shell/repos (2 files)

Bartłomiej Piotrowski bpiotrowski at archlinux.org
Fri Mar 15 11:29:55 UTC 2019


    Date: Friday, March 15, 2019 @ 11:29:54
  Author: bpiotrowski
Revision: 348142

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-shell/repos/gnome-unstable-x86_64/
  gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348141, gnome-shell/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348141, gnome-shell/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-15 11:29:54 UTC (rev 348142)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=3.32.0
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL2)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gnome-settings-daemon
+         gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libcroco libgdm libsecret
+         mutter nm-connection-editor unzip gstreamer libibus)
+makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
+             sassc)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+_commit=47915f8c1117470e5351a8ec4e4bdac5e683498d  # tags/3.32.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Move the plugin to our custom epiphany-only dir
+  sed -i "s/'mozilla'/'epiphany'/g" meson.build
+
+  git submodule init
+  git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+  
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+
+  # https://bugs.archlinux.org/task/37412
+  mkdir "$pkgdir/usr/share/gnome-shell/modes"
+}



More information about the arch-commits mailing list