[arch-commits] Commit in gnome-shell-extensions/repos (2 files)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Fri Mar 15 12:02:30 UTC 2019
Date: Friday, March 15, 2019 @ 12:02:28
Author: bpiotrowski
Revision: 348162
archrelease: copy trunk to gnome-unstable-any
Added:
gnome-shell-extensions/repos/gnome-unstable-any/
gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD
(from rev 348161, gnome-shell-extensions/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD (from rev 348161, gnome-shell-extensions/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD (rev 0)
+++ gnome-unstable-any/PKGBUILD 2019-03-15 12:02:28 UTC (rev 348162)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-shell-extensions
+pkgver=3.32.0
+pkgrel=1
+pkgdesc="Extensions for GNOME shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+makedepends=(meson git sassc js52)
+optdepends=('gnome-menus: applications menu extension')
+groups=(gnome)
+_commit=78141e6433918ff4667da242ee0dd5364ecab76d # tags/3.32.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell-extensions.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.data/gnome-shell-sass.url "$srcdir/gnome-shell-sass"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build -D extension_set=all -D classic_mode=true
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ depends=(gnome-shell)
+
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list