[arch-commits] Commit in gnome-todo/repos (2 files)

[Jan Steffens]

    Date: Friday, March 15, 2019 @ 17:35:55
  Author: heftig
Revision: 348209

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-todo/repos/gnome-unstable-x86_64/
  gnome-todo/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 348206, gnome-todo/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: gnome-todo/repos/gnome-unstable-x86_64/PKGBUILD (from rev 348206, gnome-todo/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-03-15 17:35:55 UTC (rev 348209)
@@ -0,0 +1,40 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-todo
+pkgver=3.28.1+17+gb2ffd8f
+pkgrel=1
+pkgdesc="Task manager for GNOME"
+url="https://wiki.gnome.org/Apps/Todo"
+arch=(x86_64)
+license=(GPL)
+depends=(evolution-data-server libpeas python)
+makedepends=(gobject-introspection appstream-glib git meson gtk-doc)
+groups=(gnome)
+_commit=b2ffd8f7928eae0b0f6931e619c4966fd3e94c85  # gnome-3-28
+source=("git+https://gitlab.gnome.org/GNOME/gnome-todo.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_TODO_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git cherry-pick -n 6cdabc4dd0c6c804a093b94c269461ce376fed4f  # build fix
+}
+
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set ts=2 sw=2 et: