[arch-commits] Commit in pantheon-code/repos (2 files)
Jan Steffens
heftig at archlinux.org
Fri Mar 15 19:53:15 UTC 2019
Date: Friday, March 15, 2019 @ 19:53:14
Author: heftig
Revision: 442024
archrelease: copy trunk to community-staging-x86_64
Added:
pantheon-code/repos/community-staging-x86_64/
pantheon-code/repos/community-staging-x86_64/PKGBUILD
(from rev 442022, pantheon-code/trunk/PKGBUILD)
----------+
PKGBUILD | 66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
Copied: pantheon-code/repos/community-staging-x86_64/PKGBUILD (from rev 442022, pantheon-code/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-03-15 19:53:14 UTC (rev 442024)
@@ -0,0 +1,66 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ner0 <darkelfdarkelf666 at yahoo.co.uk>
+
+pkgname=pantheon-code
+pkgver=3.1.1
+pkgrel=1
+pkgdesc='The Pantheon Text Editor'
+arch=(x86_64)
+url=https://github.com/elementary/code
+license=(GPL3)
+depends=(
+ editorconfig-core-c
+ glib2
+ gtk3
+ gtksourceview3
+ libgee
+ libgit2-glib
+ libgranite.so
+ libpeas
+ pango
+)
+makedepends=(
+ git
+ gobject-introspection
+ gtkspell3
+ intltool
+ libsoup
+ meson
+ vala
+ vte3
+ webkit2gtk
+)
+optdepends=(
+ 'gtkspell3: Spell Check plugin'
+ 'libsoup: Pastebin plugin'
+ 'vala: Outline plugin'
+ 'vte3: Terminal plugin'
+ 'webkit2gtk: Browser Preview plugin'
+)
+_commit=66f277327ba481bcc8e0bb761ee7297495a4c4ff # tags/3.1.1
+source=("pantheon-code::git+https://github.com/elementary/code.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list