[arch-commits] Commit in gthumb/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Jan Steffens heftig at archlinux.org
Fri Mar 15 21:48:28 UTC 2019


    Date: Friday, March 15, 2019 @ 21:48:27
  Author: heftig
Revision: 348409

archrelease: copy trunk to extra-x86_64

Added:
  gthumb/repos/extra-x86_64/PKGBUILD
    (from rev 348403, gthumb/trunk/PKGBUILD)
Deleted:
  gthumb/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   96 +++++++++++++++++++++++++++----------------------------------
 1 file changed, 44 insertions(+), 52 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-03-15 21:48:27 UTC (rev 348408)
+++ PKGBUILD	2019-03-15 21:48:27 UTC (rev 348409)
@@ -1,52 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-# Contributor: Tobias Kieslich <tobias at justdreams.de>
-
-pkgname=gthumb
-pkgver=3.6.2
-pkgrel=1
-pkgdesc="Image browser and viewer for the GNOME Desktop"
-url="https://wiki.gnome.org/Apps/gthumb"
-arch=(x86_64)
-license=(GPL)
-depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
-         libsecret libsoup webkit2gtk json-glib gtk3-print-backends)
-makedepends=(intltool libchamplain exiv2 itstool brasero libraw liboauth docbook-xsl
-             yelp-tools flex gnome-common git)
-optdepends=('libraw: read RAW files'
-            'exiv2: metadata support'
-            'libchamplain: map viewer'
-            'brasero: burn discs'
-            'liboauth: web albums')
-_commit=28f951e14aae66b96d7a03aa887ca3844824cecb  # tags/3.6.2^0
-source=("git+https://gitlab.gnome.org/GNOME/gthumb.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd $pkgname
-  ./configure --prefix=/usr --sysconfdir=/etc \
-      --localstatedir=/var --disable-static \
-      --enable-libchamplain
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-  make
-}
-
-check() {
-  cd $pkgname
-  make check
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-}

Copied: gthumb/repos/extra-x86_64/PKGBUILD (from rev 348403, gthumb/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-03-15 21:48:27 UTC (rev 348409)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+
+pkgname=gthumb
+pkgver=3.7.1
+pkgrel=1
+pkgdesc="Image browser and viewer for the GNOME Desktop"
+url="https://wiki.gnome.org/Apps/gthumb"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
+         libsecret libsoup webkit2gtk json-glib gtk3-print-backends)
+makedepends=(libchamplain exiv2 brasero libraw liboauth docbook-xsl yelp-tools meson git)
+optdepends=('libraw: read RAW files'
+            'exiv2: metadata support'
+            'libchamplain: map viewer'
+            'brasero: burn discs'
+            'liboauth: web albums')
+_commit=c2a0c415679b511d5f5436d89edff3445250d63a  # tags/3.7.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gthumb.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build -D libchamplain=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}


More information about the arch-commits mailing list