[arch-commits] Commit in gnome-software/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Friday, March 15, 2019 @ 21:59:27
  Author: heftig
Revision: 442057

archrelease: copy trunk to community-x86_64

Added:
  gnome-software/repos/community-x86_64/PKGBUILD
    (from rev 442056, gnome-software/trunk/PKGBUILD)
Deleted:
  gnome-software/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  128 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 68 insertions(+), 60 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-03-15 21:58:52 UTC (rev 442056)
+++ PKGBUILD	2019-03-15 21:59:27 UTC (rev 442057)
@@ -1,60 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
-
-pkgbase=gnome-software
-pkgname=(gnome-software gnome-software-packagekit-plugin)
-pkgver=3.30.6
-pkgrel=1
-pkgdesc="GNOME Software Tools"
-url="https://wiki.gnome.org/Apps/Software/"
-arch=(x86_64)
-license=(GPL2)
-makedepends=(appstream-glib gnome-desktop libpackagekit-glib flatpak fwupd ostree
-             docbook-xsl git gobject-introspection gspell gtk-doc meson valgrind)
-_commit=ae42d5130a200a0fe60c011f29e4e699be639cf4  # tags/3.30.6^0
-source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgbase
-  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgbase
-}
-
-build() {
-  arch-meson $pkgbase build \
-    -D ubuntuone=false \
-    -D ubuntu_reviews=false
-  ninja -C build
-}
-
-check() {
-  # build container troubles
-  meson test -C build || :
-}
-
-package_gnome-software() {
-  groups=('gnome')
-  depends=(appstream-glib gnome-desktop gsettings-desktop-schemas gspell libpackagekit-glib)
-  optdepends=('flatpak: Flatpak support plugin'
-              'fwupd: fwupd support plugin'
-              'ostree: OSTree support plugin')
-
-  DESTDIR="$pkgdir" meson install -C build
-
-  # Split out packagekit plugin
-  mkdir "$srcdir"/packagekit-plugin
-  mv "$pkgdir"/usr/lib/gs-plugins-12/libgs_plugin_{packagekit*,systemd-updates}.so "$srcdir"/packagekit-plugin
-}
-
-package_gnome-software-packagekit-plugin() {
-  pkgdesc="PackageKit support plugin for GNOME Software"
-  depends=(archlinux-appstream-data gnome-software packagekit)
-
-  mkdir -p "$pkgdir"/usr/lib/gs-plugins-12
-  mv "$srcdir"/packagekit-plugin/* "$pkgdir"/usr/lib/gs-plugins-12/
-}

Copied: gnome-software/repos/community-x86_64/PKGBUILD (from rev 442056, gnome-software/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-03-15 21:59:27 UTC (rev 442057)
@@ -0,0 +1,68 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=3.32.0
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL2)
+makedepends=(appstream-glib gnome-desktop libpackagekit-glib flatpak fwupd ostree
+             docbook-xsl git gobject-introspection gspell gtk-doc meson valgrind
+             gnome-online-accounts libxmlb)
+_commit=bed994cc6e3c41a92efd6b2847ef978d5b2cd3a3  # tags/3.32.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build
+  ninja -C build
+}
+
+check() {
+  # build container troubles
+  meson test -C build --print-errorlogs || :
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_gnome-software() {
+  groups=('gnome')
+  depends=(libxmlb gnome-desktop gsettings-desktop-schemas gspell libpackagekit-glib
+           gnome-online-accounts)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'ostree: OSTree support plugin')
+
+  DESTDIR="$pkgdir" meson install -C build
+
+### Split gnome-software-packagekit-plugin
+  _pick packagekit-plugin "$pkgdir"/usr/lib/gs-plugins-*/libgs_plugin_packagekit*.so
+  _pick packagekit-plugin "$pkgdir"/usr/lib/gs-plugins-*/libgs_plugin_systemd-updates.so
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit appstream-glib)
+  mv packagekit-plugin/* "$pkgdir"
+}