[arch-commits] Commit in stylish-haskell/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Mar 16 03:16:54 UTC 2019


    Date: Saturday, March 16, 2019 @ 03:16:53
  Author: felixonmars
Revision: 442105

archrelease: copy trunk to community-staging-x86_64

Added:
  stylish-haskell/repos/community-staging-x86_64/
  stylish-haskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 442104, stylish-haskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: stylish-haskell/repos/community-staging-x86_64/PKGBUILD (from rev 442104, stylish-haskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-16 03:16:53 UTC (rev 442105)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=stylish-haskell
+pkgver=0.9.2.1
+pkgrel=11
+pkgdesc="Haskell code prettifier"
+url="https://github.com/jaspervdj/stylish-haskell"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-file-embed' 'haskell-optparse-applicative'
+         'haskell-src-exts' 'haskell-strict' 'haskell-syb' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-test-framework' 'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('580353475fbd400bae4d7e7e4177ce3799b657601f29ad8158959ea8a40f875a9575b8b02a1a36f4e9c364ab5e266408ef2b3a004a09db6286e139e67c954d6d')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e '/semigroups/d' -e 's/< *1.21/<2/' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old_base
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list