[arch-commits] Commit in netcdf-fortran-openmpi/repos (2 files)

Bruno Pagani archange at archlinux.org
Sun Mar 17 12:30:11 UTC 2019


    Date: Sunday, March 17, 2019 @ 12:30:10
  Author: archange
Revision: 442365

archrelease: copy trunk to community-staging-x86_64

Added:
  netcdf-fortran-openmpi/repos/community-staging-x86_64/
  netcdf-fortran-openmpi/repos/community-staging-x86_64/PKGBUILD
    (from rev 442364, netcdf-fortran-openmpi/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: netcdf-fortran-openmpi/repos/community-staging-x86_64/PKGBUILD (from rev 442364, netcdf-fortran-openmpi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-17 12:30:10 UTC (rev 442365)
@@ -0,0 +1,52 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+_pkg=netcdf-fortran
+_mpi=openmpi
+pkgname=${_pkg}-${_mpi}
+pkgver=4.4.5
+pkgrel=2
+pkgdesc="NetCDF fortran bindings with parallel support (${_mpi} version)"
+arch=('x86_64')
+url="https://github.com/Unidata/netcdf-fortran"
+license=('custom')
+depends=('gcc-libs' 'netcdf-openmpi' 'curl')
+makedepends=('gcc-fortran' 'doxygen')
+checkdepends=('valgrind')
+provides=("${_pkg}")
+conflicts=("${_pkg}")
+options=('!makeflags' 'staticlibs')
+source=(${_pkg}-${pkgver}.tar.gz::"${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('01643461ac42d1986e38a052eb021135bae5b6cd592373fb44cf832236791c03')
+
+build() {
+    cd ${_pkg}-${pkgver}
+    ./configure \
+        CC=mpicc \
+        FC=mpifort \
+        --prefix=/usr \
+        --enable-extra-tests \
+        --enable-extra-example-tests \
+        --enable-large-file-tests \
+        --enable-parallel-tests \
+        --enable-valgrind-tests
+    make
+}
+
+check() {
+    cd ${_pkg}-${pkgver}
+
+    # This is required starting with OpenMPI 3.0 when trying to run more
+    # processes than the number of available cores
+    export OMPI_MCA_rmaps_base_oversubscribe=yes
+
+    # https://github.com/Unidata/netcdf-fortran/issues/109
+    make LIBS="-lnetcdf -lhdf5_hl -lhdf5 -lpnetcdf -lz -lcurl -ldl -lm" check || warning "Tests failed"
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${_pkg}/
+}


More information about the arch-commits mailing list