[arch-commits] Commit in (4 files)

[Chih-Hsuan Yen]

    Date: Wednesday, March 20, 2019 @ 11:30:59
  Author: yan12125
Revision: 442933

capitaine-cursors: new package, version 3-2

* 63 votes with popularity=3.530887 on AUR
* Included in 453 submissions to pkgstats.archlinux.de
* I love it and have used it for a long time :)

Added:
  capitaine-cursors/
  capitaine-cursors/repos/
  capitaine-cursors/trunk/
  capitaine-cursors/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: capitaine-cursors/trunk/PKGBUILD
===================================================================
--- capitaine-cursors/trunk/PKGBUILD	                        (rev 0)
+++ capitaine-cursors/trunk/PKGBUILD	2019-03-20 11:30:59 UTC (rev 442933)
@@ -0,0 +1,33 @@
+# Maintainer: Chih-Hsuan Yen <yan121215 at archlinux.org>
+# Contributor: Ye Jingchen <ye.jingchen at gmail.com>
+
+pkgname=capitaine-cursors
+pkgver=3
+pkgrel=2
+pkgdesc="An x-cursor theme inspired by macOS and based on KDE Breeze"
+arch=(any)
+url="https://github.com/keeferrourke/capitaine-cursors"
+license=(LGPL3)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/keeferrourke/$pkgname/archive/r$pkgver.tar.gz")
+makedepends=(inkscape xorg-xcursorgen)
+sha256sums=('226258d7d07648c27d8ecfb2085a1af4bcc37e49df497fcd371950f7c42ae090')
+
+prepare() {
+  cd $pkgname-r$pkgver
+  # Remove prebuilt assets
+  rm -rf dist/
+}
+
+build() {
+  cd $pkgname-r$pkgver
+  bash -e ./build.sh
+}
+
+package() {
+  cd $pkgname-r$pkgver
+  install -Ddm755 "$pkgdir/usr/share/icons"
+  cp -dr --no-preserve=ownership dist/ "$pkgdir/usr/share/icons/capitaine-cursors"
+  # inconsistency naming in upstream releases...
+  # https://github.com/keeferrourke/capitaine-cursors/releases
+  cp -dr --no-preserve=ownership dist-white/ "$pkgdir/usr/share/icons/capitaine-cursors-light"
+}