[arch-commits] Commit in python-autobahn/repos (3 files)
Chih-Hsuan Yen
yan12125 at archlinux.org
Fri Mar 22 17:12:26 UTC 2019
Date: Friday, March 22, 2019 @ 17:12:25
Author: yan12125
Revision: 443157
archrelease: copy trunk to community-testing-any
Added:
python-autobahn/repos/community-testing-any/
python-autobahn/repos/community-testing-any/PKGBUILD
(from rev 443156, python-autobahn/trunk/PKGBUILD)
python-autobahn/repos/community-testing-any/skip-test-missing-serializers.patch
(from rev 443156, python-autobahn/trunk/skip-test-missing-serializers.patch)
-------------------------------------+
PKGBUILD | 47 ++++++++++++++++++++++++++++++++++
skip-test-missing-serializers.patch | 34 ++++++++++++++++++++++++
2 files changed, 81 insertions(+)
Copied: python-autobahn/repos/community-testing-any/PKGBUILD (from rev 443156, python-autobahn/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2019-03-22 17:12:25 UTC (rev 443157)
@@ -0,0 +1,47 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Maintainer: Anatol Pomozov
+
+pkgname=python-autobahn
+pkgver=19.3.2
+pkgrel=1
+pkgdesc='Real-time framework for Web, Mobile & Internet of Things'
+arch=(any)
+url='https://crossbar.io/autobahn/'
+license=(MIT)
+depends=(python-twisted python-six python-txaio python-wsaccel)
+makedepends=(python-setuptools python-argon2_cffi python-msgpack python-passlib python-pynacl)
+checkdepends=(python-mock python-pytest python-pytest-asyncio)
+optdepends=(
+ 'python-msgpack: MsgPack serializer support'
+ 'python-argon2_cffi: WAMP-SCRAM authentication support'
+ 'python-passlib: WAMP-SCRAM authentication support'
+ 'python-pynacl: WAMP-cryptosign support'
+)
+
+source=(https://pypi.io/packages/source/a/autobahn/autobahn-$pkgver.tar.gz
+ skip-test-missing-serializers.patch)
+sha256sums=('70a221d5e01923ea81457de04a3270ea2de376a759345ec4e8693db216c603a9'
+ '2d4ec4300f98cddd13c3a4d70e6ae4934a98f17b04628cadfd18654172d04f92')
+
+prepare() {
+ cd "$srcdir/autobahn-$pkgver"
+ patch -Np1 -i ../skip-test-missing-serializers.patch
+}
+
+build() {
+ cd "$srcdir/autobahn-$pkgver"
+ python setup.py build
+}
+
+check() {
+ cd "$srcdir/autobahn-$pkgver"
+ USE_TWISTED=1 PYTHONPATH=. pytest -v autobahn
+ USE_ASYNCIO=1 PYTHONPATH=. pytest -v autobahn
+}
+
+package() {
+ cd "$srcdir/autobahn-$pkgver"
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
Copied: python-autobahn/repos/community-testing-any/skip-test-missing-serializers.patch (from rev 443156, python-autobahn/trunk/skip-test-missing-serializers.patch)
===================================================================
--- community-testing-any/skip-test-missing-serializers.patch (rev 0)
+++ community-testing-any/skip-test-missing-serializers.patch 2019-03-22 17:12:25 UTC (rev 443157)
@@ -0,0 +1,34 @@
+diff --git a/autobahn/wamp/test/test_serializer.py b/autobahn/wamp/test/test_serializer.py
+index 8e47805c..117df18d 100644
+--- a/autobahn/wamp/test/test_serializer.py
++++ b/autobahn/wamp/test/test_serializer.py
+@@ -129,11 +129,17 @@ def create_serializers():
+ _serializers.append(serializer.MsgPackSerializer())
+ _serializers.append(serializer.MsgPackSerializer(batched=True))
+
+- _serializers.append(serializer.CBORSerializer())
+- _serializers.append(serializer.CBORSerializer(batched=True))
++ try:
++ _serializers.append(serializer.CBORSerializer())
++ _serializers.append(serializer.CBORSerializer(batched=True))
++ except AttributeError:
++ pass
+
+- _serializers.append(serializer.UBJSONSerializer())
+- _serializers.append(serializer.UBJSONSerializer(batched=True))
++ try:
++ _serializers.append(serializer.UBJSONSerializer())
++ _serializers.append(serializer.UBJSONSerializer(batched=True))
++ except AttributeError:
++ pass
+
+ # FIXME: implement full FlatBuffers serializer for WAMP
+ if six.PY3:
+@@ -146,6 +152,7 @@ def create_serializers():
+
+
+ @unittest.skipIf(not six.PY3, 'WAMP-FlatBuffers currently only supports Python 3')
++ at unittest.skipIf(not hasattr(serializer, 'FlatBuffersSerializer'), 'FlatBuffers support missing')
+ class TestFlatBuffersSerializer(unittest.TestCase):
+
+ def test_basic(self):
More information about the arch-commits
mailing list