[arch-commits] Commit in marble/repos (2 files)

[Antonio Rojas]

    Date: Saturday, March 23, 2019 @ 00:23:28
  Author: arojas
Revision: 348957

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  marble/repos/kde-unstable-x86_64/
  marble/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 348956, marble/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   81 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

Copied: marble/repos/kde-unstable-x86_64/PKGBUILD (from rev 348956, marble/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2019-03-23 00:23:28 UTC (rev 348957)
@@ -0,0 +1,81 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+
+pkgbase=marble
+pkgname=(marble-common marble-qt marble)
+pkgver=19.03.80
+pkgrel=1
+pkgdesc="Desktop Globe"
+arch=(x86_64)
+url="https://www.kde.org/applications/system/marble"
+license=(GPL)
+makedepends=(extra-cmake-modules gpsd kdoctools knewstuff kparts krunner libwlocate phonon-qt5
+             plasma-workspace qt5-serialport qt5-tools qt5-webengine shapelib)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('1f81bf6dc13a31f0b856e3600792a0ae52c25143d2e4c3556b7f7cee89d8683f'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+    -DQT_PLUGINS_DIR=lib/qt/plugins \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_MARBLE_EXAMPLES=OFF \
+    -DBUILD_MARBLE_TESTS=OFF \
+    -DMOBILE=OFF
+  make
+}
+
+package_marble-common() {
+  pkgdesc='Common libraries and plugins for Marble'
+  depends=(qt5-svg qt5-webengine phonon-qt5 desktop-file-utils)
+  optdepends=('gpsd: GPS based geolocation'
+              'libwlocate: WLAN based geolocation'
+              'qt5-serialport: APRS plugin'
+              'shapelib: SHP plugin')
+  conflicts=(marble-data)
+  replaces=(marble-data libastro)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/usr/share/{config.kcfg,kxmlgui5,metainfo,plasma} \
+        "$pkgdir"/usr/bin \
+        "$pkgdir"/etc \
+        "$pkgdir"/usr/lib/qt/{qml,plugins/*.so} \
+        "$pkgdir"/usr/share/applications/{marble_geo.desktop,marble_worldwind.desktop,org.kde.marble*.desktop} \
+        "$pkgdir"/usr/share/kservices5/{marble_part.desktop,plasma*} \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/*.mo
+}
+
+package_marble-qt() {
+  pkgdesc+=' (Qt version)'
+  depends=(marble-common)
+
+  cd build
+  make -C src/apps/marble-qt DESTDIR="$pkgdir" install
+}
+
+package_marble() {
+  depends=(marble-common knewstuff kparts)
+  optdepends=('krunner: Krunner plugin')
+  groups=(kde-applications kdeedu)
+
+  cd build
+  make -C src/apps/marble-kde DESTDIR="$pkgdir" install
+  make -C src/plasma DESTDIR="$pkgdir" install
+  make -C src/plasmarunner DESTDIR="$pkgdir" install
+  make -C src/thumbnailer DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/usr/share/{icons,doc/HTML}
+}