[arch-commits] Commit in kdenlive/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Sat Mar 23 00:43:26 UTC 2019
Date: Saturday, March 23, 2019 @ 00:43:23
Author: arojas
Revision: 349048
archrelease: copy kde-unstable to kde-unstable-x86_64
Added:
kdenlive/repos/kde-unstable-x86_64/
kdenlive/repos/kde-unstable-x86_64/PKGBUILD
(from rev 349047, kdenlive/kde-unstable/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: kdenlive/repos/kde-unstable-x86_64/PKGBUILD (from rev 349047, kdenlive/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD (rev 0)
+++ kde-unstable-x86_64/PKGBUILD 2019-03-23 00:43:23 UTC (rev 349048)
@@ -0,0 +1,49 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Zuf <kontakt.zuf at gmail.com>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=kdenlive
+pkgver=19.03.80
+pkgrel=1
+pkgdesc="A non-linear video editor for Linux using the MLT video framework"
+arch=(x86_64)
+url="https://www.kdenlive.org/"
+license=(GPL)
+groups=(kde-applications kdemultimedia)
+depends=(knewstuff knotifyconfig kfilemetadata purpose mlt glu qt5-quickcontrols rttr)
+makedepends=(extra-cmake-modules kdoctools v4l-utils)
+optdepends=('ffmpeg: for FFmpeg plugin'
+ 'cdrtools: for creation of DVD ISO images'
+ 'dvdauthor: for creation of DVD'
+ 'dvgrab: for firewire capture'
+ 'recordmydesktop: for screen capture'
+ 'xine-ui: for DVD preview'
+ 'vlc: for DVD preview'
+ 'plasma-desktop: theme configuration')
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('c2ca20645ac2de2a012cb0fe5b1323889f1a5418a4968e4ac4bd888381b502ea'
+ 'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid at kde.org>
+ F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+ mkdir -p build
+
+ sed -e 's|RTTR::Core_Lib|RTTR::Core|g' -i $pkgname-$pkgver/src/CMakeLists.txt # Fix build with system rttr
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list