[arch-commits] Commit in haskell-hpack/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Mar 25 07:32:53 UTC 2019


    Date: Monday, March 25, 2019 @ 07:32:52
  Author: felixonmars
Revision: 443381

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hpack/repos/community-staging-x86_64/
  haskell-hpack/repos/community-staging-x86_64/PKGBUILD
    (from rev 443380, haskell-hpack/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-hpack/repos/community-staging-x86_64/PKGBUILD (from rev 443380, haskell-hpack/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-25 07:32:52 UTC (rev 443381)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+pkgname=haskell-hpack
+_hkgname=hpack
+pkgver=0.31.2
+pkgrel=2
+pkgdesc="A modern format for Haskell packages"
+url="https://github.com/sol/hpack#readme"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-bifunctors' 'haskell-cryptonite' 'haskell-glob'
+         'haskell-http-client' 'haskell-http-client-tls' 'haskell-http-types'
+         'haskell-infer-license' 'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-hspec' 'haskell-interpolate'
+             'haskell-mockery' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
+sha512sums=('8476463d34a4f110362e09e2b64fa091776c8742b217be26de8cddd932ae850eb63d2ba241021e4f2a1528a10b5852bba7bccdb8b7248e6ced534d45a6c39542')
+
+build() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
+}


More information about the arch-commits mailing list