[arch-commits] Commit in haskell-uri-bytestring/repos (2 files)

[Felix Yan]

    Date: Tuesday, March 26, 2019 @ 23:33:19
  Author: felixonmars
Revision: 443885

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-uri-bytestring/repos/community-staging-x86_64/
  haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD
    (from rev 443884, haskell-uri-bytestring/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD (from rev 443884, haskell-uri-bytestring/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-26 23:33:19 UTC (rev 443885)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=uri-bytestring
+pkgname=haskell-uri-bytestring
+pkgver=0.3.2.1
+pkgrel=15
+pkgdesc="Haskell URI parsing as ByteStrings"
+url="https://github.com/Soostone/uri-bytestring"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-th-lift-instances')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-base-compat' 'haskell-quickcheck-instances'
+             'haskell-generics-sop')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('78c97321fad344502f6d144e763d1a5406c1d8cde7164470e9803b9d5e214d7aaea8430fc8a594d733ddc773cf59a8e050dd2a514e0d1e9eaeebf15f40fe74a8')
+
+prepare() {
+    sed -e '/, semigroups/d' -i ${_hkgname}-${pkgver}/${_hkgname}.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --disable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-lib-Werror
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/Soostone/uri-bytestring/issues/50
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}