[arch-commits] Commit in libcurl-compat/repos (2 files)
Christian Hesse
eworm at archlinux.org
Wed Mar 27 09:52:26 UTC 2019
Date: Wednesday, March 27, 2019 @ 09:52:25
Author: eworm
Revision: 444160
archrelease: copy trunk to community-testing-x86_64
Added:
libcurl-compat/repos/community-testing-x86_64/
libcurl-compat/repos/community-testing-x86_64/PKGBUILD
(from rev 444159, libcurl-compat/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: libcurl-compat/repos/community-testing-x86_64/PKGBUILD (from rev 444159, libcurl-compat/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2019-03-27 09:52:25 UTC (rev 444160)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Piotr Balcerowski <piotr at balcerowski.org>
+
+pkgname=libcurl-compat
+pkgver=7.64.1
+pkgrel=1
+pkgdesc='An URL retrieval library (without versioned symbols)'
+arch=('x86_64')
+url='https://curl.haxx.se'
+license=('MIT')
+depends=('curl' 'glibc' 'krb5' 'openssl' 'libpsl' 'zlib'
+ 'libssh2.so')
+options=('strip')
+source=("https://curl.haxx.se/download/curl-${pkgver}.tar.gz"{,.asc})
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+sha512sums=('c8f8c4397e0e2975e7553f36637b7e7caa29d7953229dcf4d8051f9bae0cf55572d6e25fc27d9c34fe8783cf87893d96d447601c74662374b8bbd393b6cb6825'
+ 'SKIP')
+
+build() {
+ cd curl-${pkgver}
+
+ ./configure \
+ --prefix='/usr' \
+ --disable-ldap \
+ --disable-ldaps \
+ --disable-manual \
+ --disable-versioned-symbols \
+ --enable-ipv6 \
+ --enable-threaded-resolver \
+ --with-gssapi \
+ --with-libssh2 \
+ --with-random='/dev/urandom' \
+ --with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make -C lib
+}
+
+package() {
+ cd curl-${pkgver}
+
+ make -C lib DESTDIR="${pkgdir}" install
+
+ mv "${pkgdir}"/usr/lib/libcurl{,-compat}.so.4.5.0
+ rm "${pkgdir}"/usr/lib/libcurl.{a,so}*
+ for version in 3 4.0.0 4.1.0 4.2.0 4.3.0 4.4.0; do
+ ln -s libcurl-compat.so.4.5.0 "${pkgdir}"/usr/lib/libcurl.so.${version}
+ done
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s curl "${pkgdir}"/usr/share/licenses/libcurl-compat
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list