[arch-commits] Commit in lib32-curl/repos (2 files)

Christian Hesse eworm at archlinux.org
Wed Mar 27 09:53:39 UTC 2019


    Date: Wednesday, March 27, 2019 @ 09:53:38
  Author: eworm
Revision: 444164

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-curl/repos/multilib-testing-x86_64/
  lib32-curl/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 444163, lib32-curl/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: lib32-curl/repos/multilib-testing-x86_64/PKGBUILD (from rev 444163, lib32-curl/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2019-03-27 09:53:38 UTC (rev 444164)
@@ -0,0 +1,58 @@
+# Maintainer: Daniel Wallace <danielwallace at aur.archlinux.org>
+# Contributor: Dave Reisner <dreisner at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Lucien Immink <l.immink at student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=lib32-curl
+_pkgname=curl
+pkgver=7.64.1
+pkgrel=1
+pkgdesc="An URL retrieval utility and library (32-bit)"
+arch=('x86_64')
+url="https://curl.haxx.se"
+license=('MIT')
+depends=('lib32-libssh2' 'lib32-krb5' 'lib32-libpsl' 'lib32-zlib' "${_pkgname}")
+source=("https://curl.haxx.se/download/$_pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('c8f8c4397e0e2975e7553f36637b7e7caa29d7953229dcf4d8051f9bae0cf55572d6e25fc27d9c34fe8783cf87893d96d447601c74662374b8bbd393b6cb6825'
+            'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --with-gssapi \
+      --with-libssh2 \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+      --libdir=/usr/lib32
+
+  make
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "${pkgdir}"/usr/{share,bin,include}
+
+  # license
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"
+}


More information about the arch-commits mailing list