[arch-commits] Commit in gst-plugins-ugly/repos (2 files)

Maxime Gauduin alucryd at archlinux.org
Wed Mar 27 12:32:05 UTC 2019


    Date: Wednesday, March 27, 2019 @ 12:32:04
  Author: alucryd
Revision: 349270

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-ugly/repos/staging-x86_64/
  gst-plugins-ugly/repos/staging-x86_64/PKGBUILD
    (from rev 349269, gst-plugins-ugly/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: gst-plugins-ugly/repos/staging-x86_64/PKGBUILD (from rev 349269, gst-plugins-ugly/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-03-27 12:32:04 UTC (rev 349270)
@@ -0,0 +1,59 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-ugly
+pkgver=1.14.4
+pkgrel=2
+pkgdesc="GStreamer Multimedia Framework Ugly Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gst-plugins-base-libs libdvdread libmpeg2 a52dec libsidplay libcdio
+         x264 opencore-amr)
+makedepends=(python gtk-doc autoconf-archive git)
+_commit=e1bf2aa184f83ff9fd5b7850c460129100ac6d1a  # tags/1.14.4^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-ugly.git#commit=$_commit"
+        "gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib \
+    --with-package-name="GStreamer Ugly Plugins (Arch Linux)" \
+    --with-package-origin="https://www.archlinux.org/" \
+    --enable-experimental \
+    --enable-gtk-doc \
+    --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list