[arch-commits] Commit in haskell-binary-tagged/repos (2 files)

[Felix Yan]

    Date: Thursday, March 28, 2019 @ 06:16:00
  Author: felixonmars
Revision: 445103

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-binary-tagged/repos/community-staging-x86_64/
  haskell-binary-tagged/repos/community-staging-x86_64/PKGBUILD
    (from rev 445102, haskell-binary-tagged/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-binary-tagged/repos/community-staging-x86_64/PKGBUILD (from rev 445102, haskell-binary-tagged/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-28 06:16:00 UTC (rev 445103)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=binary-tagged
+pkgname=haskell-binary-tagged
+pkgver=0.1.5.1
+pkgrel=22
+pkgdesc="Tagged binary serialisation."
+url="https://github.com/phadej/binary-tagged#readme"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base16-bytestring' 'haskell-generics-sop'
+         'haskell-hashable' 'haskell-scientific' 'haskell-sha' 'haskell-tagged'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6df6475f84b7158bbc9272d6f5487997416f1dea7bc5954ae0015f253e446a22854282c1c36888dcf2a714a56263216b5582c1add8aad428331c24957d44ae88')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *0.4/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}