[arch-commits] Commit in handbrake/repos (2 files)
Maxime Gauduin
alucryd at archlinux.org
Thu Mar 28 08:04:35 UTC 2019
Date: Thursday, March 28, 2019 @ 08:04:35
Author: alucryd
Revision: 445219
archrelease: copy trunk to community-staging-x86_64
Added:
handbrake/repos/community-staging-x86_64/
handbrake/repos/community-staging-x86_64/PKGBUILD
(from rev 445218, handbrake/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: handbrake/repos/community-staging-x86_64/PKGBUILD (from rev 445218, handbrake/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-03-28 08:04:35 UTC (rev 445219)
@@ -0,0 +1,54 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.2.2
+pkgrel=2
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+makedepends=('intltool' 'python2' 'nasm' 'wget' 'cmake' 'bzip2' 'gcc-libs' 'xz'
+ 'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
+ 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
+ 'speex' 'x264' 'jansson' 'librsvg' 'libgudev')
+source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2
+ https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2.sig)
+sha256sums=('df6816f517d60ae8a6626aa731821af2d1966c155fa53b2b9a06c47f3c565e4c'
+ 'SKIP')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+build() {
+ cd "$srcdir/HandBrake-$pkgver"
+
+ ./configure --prefix=/usr
+ make -C build
+}
+
+package_handbrake() {
+ pkgdesc="Multithreaded video transcoder"
+ depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
+ 'gtk3' 'xz' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
+ 'libsamplerate' 'speex' 'x264' 'jansson' 'librsvg' 'libgudev'
+ 'desktop-file-utils' 'hicolor-icon-theme')
+ optdepends=('gst-plugins-good: for video previews'
+ 'gst-libav: for video previews'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+
+ make DESTDIR="$pkgdir" install
+ rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+ pkgdesc="Multithreaded video transcoder (CLI)"
+ depends=('bzip2' 'gcc-libs' 'zlib' 'xz' 'libass' 'lame' 'libxml2' 'opus'
+ 'libvorbis' 'libtheora' 'libsamplerate' 'speex' 'x264' 'jansson')
+ optdepends=('libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+ install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list