[arch-commits] Commit in ftgl/repos/extra-x86_64 (PKGBUILD PKGBUILD)
Jan Steffens
heftig at archlinux.org
Thu Mar 28 15:59:40 UTC 2019
Date: Thursday, March 28, 2019 @ 15:59:39
Author: heftig
Revision: 349373
archrelease: copy trunk to extra-x86_64
Added:
ftgl/repos/extra-x86_64/PKGBUILD
(from rev 349372, ftgl/trunk/PKGBUILD)
Deleted:
ftgl/repos/extra-x86_64/PKGBUILD
----------+
PKGBUILD | 87 ++++++++++++++++++++++++++++++++-----------------------------
1 file changed, 47 insertions(+), 40 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2019-03-28 15:43:33 UTC (rev 349372)
+++ PKGBUILD 2019-03-28 15:59:39 UTC (rev 349373)
@@ -1,40 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Alexander Baldeck <alexander at archlinux.org>
-# Contributor: tobias <tobias at archlinux.org>
-
-pkgname=ftgl
-_pkgver=2.1.3-rc5
-pkgver=${_pkgver/-/}
-pkgrel=10
-pkgdesc="OpenGL library to use arbitrary fonts"
-arch=(i686 x86_64)
-url="https://sourceforge.net/projects/ftgl/"
-license=(MIT)
-depends=(freetype2 glu)
-makedepends=(doxygen mesa graphviz)
-source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$_pkgver.tar.bz2")
-sha256sums=('521ff7bd62c459ff5372e269c223e2a6107a6a99a36afdc2ae634a973af70c59')
-
-prepare() {
- cd $pkgname-${_pkgver/-/\~}
- sed -i '/^SUBDIRS =/s/demo//' Makefile.in
- printf '%s\n' >>docs/doxygen.cfg.in \
- HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
-}
-
-build() {
- cd $pkgname-${_pkgver/-/\~}
- ./configure --prefix=/usr --with-pic --disable-static
- make
-}
-
-package() {
- cd $pkgname-${_pkgver/-/\~}
- make DESTDIR="$pkgdir" install
-
- # FS#23283: install missing headers for OpenCascade
- install -m644 src/FT{Face,Library,Size}.h "$pkgdir/usr/include/FTGL/"
-
- install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}
Copied: ftgl/repos/extra-x86_64/PKGBUILD (from rev 349372, ftgl/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2019-03-28 15:59:39 UTC (rev 349373)
@@ -0,0 +1,47 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Alexander Baldeck <alexander at archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=ftgl
+_pkgver=2.1.3-rc5
+pkgver=2.4.0
+pkgrel=1
+pkgdesc="OpenGL library to use arbitrary fonts"
+arch=(x86_64)
+url="https://github.com/frankheckenbach/ftgl"
+license=(MIT)
+depends=(freetype2 glu)
+makedepends=(doxygen mesa graphviz git)
+_commit=483639219095ad080538e07ceb5996de901d4e74 # tags/v2.4.0
+source=("git+https://github.com/frankheckenbach/ftgl#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ printf '%s\n' >>docs/doxygen.cfg.in \
+ HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+ ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --with-pic --disable-static
+ make
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+
+ # FS#23283: install missing headers for OpenCascade
+ install -Dt "$pkgdir/usr/include/FTGL" -m644 src/FT{Face,Size}.h
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list