[arch-commits] Commit in (4 files)
Christian Rebischke
shibumi at archlinux.org
Fri Mar 29 14:16:23 UTC 2019
Date: Friday, March 29, 2019 @ 14:16:23
Author: shibumi
Revision: 446018
added minikube
Added:
minikube/
minikube/repos/
minikube/trunk/
minikube/trunk/PKGBUILD
----------+
PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
1 file changed, 36 insertions(+)
Added: minikube/trunk/PKGBUILD
===================================================================
--- minikube/trunk/PKGBUILD (rev 0)
+++ minikube/trunk/PKGBUILD 2019-03-29 14:16:23 UTC (rev 446018)
@@ -0,0 +1,36 @@
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
+
+pkgname=minikube
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Minikube is a tool that makes it easy to run Kubernetes locally"
+url="https://github.com/kubernetes/minikube"
+license=('Apache')
+arch=('x86_64')
+optdepends=(
+ 'kubectl: to manage the cluster'
+ 'virtualbox: to use --vm-driver=virtualbox'
+)
+makedepends=('git' 'go' 'go-bindata')
+source=("git+https://github.com/kubernetes/minikube.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ rm -rf "$srcdir/src"
+ mkdir -p "$srcdir/src/k8s.io"
+ mv -T "$srcdir/minikube" "$srcdir/src/k8s.io/minikube"
+}
+
+build() {
+ export GOPATH="$srcdir"
+ cd "$GOPATH/src/k8s.io/minikube"
+ make
+}
+
+package() {
+ install -Dm755 "$srcdir/src/k8s.io/minikube/out/minikube" -t "$pkgdir/usr/bin"
+
+ "$pkgdir/usr/bin/minikube" completion bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/minikube"
+ "$pkgdir/usr/bin/minikube" completion zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_minikube"
+}
More information about the arch-commits
mailing list