[arch-commits] Commit in fluid/repos (2 files)

[Felix Yan]

    Date: Sunday, March 31, 2019 @ 05:11:42
  Author: felixonmars
Revision: 446459

archrelease: copy trunk to community-testing-x86_64

Added:
  fluid/repos/community-testing-x86_64/
  fluid/repos/community-testing-x86_64/PKGBUILD
    (from rev 446458, fluid/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: fluid/repos/community-testing-x86_64/PKGBUILD (from rev 446458, fluid/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-03-31 05:11:42 UTC (rev 446459)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=fluid
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Library for QtQuick apps with Material Design and Universal"
+arch=('x86_64')
+url='https://github.com/lirios/fluid'
+license=('MPL')
+depends=('qt5-graphicaleffects' 'qt5-quickcontrols2' 'qt5-svg')
+makedepends=('liri-qbs-shared' 'nodejs-material-design-icons' 'qt5-tools' 'clang')
+replaces=('qml-material')
+groups=('liri')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lirios/fluid/archive/v$pkgver.tar.gz")
+sha512sums=('73796930c6273c2fcc89cfe54d1b5cb34a98a3f4af5f564da305efa83e4ef4e451d1244f3b59edaa76a17ef09de066966598f85f67f0dd7442f2ca0e123d55a9')
+
+prepare() {
+  cd fluid-$pkgver
+  ln -s /usr/lib/node_modules/material-design-icons
+  sed -e '/git clone/d' -e '/rm -rf/d' -i scripts/fetch_icons.sh
+  scripts/fetch_icons.sh
+}
+
+build() {
+  export QT_VER=5.12
+
+  cd fluid-$pkgver
+  qbs setup-toolchains --type gcc /usr/bin/g++ gcc
+  qbs setup-qt /usr/bin/qmake-qt5 qt5
+  qbs config profiles.qt5.baseProfile gcc
+  qbs build --no-install -d build profile:qt5 modules.lirideployment.prefix:/usr \
+                                              modules.lirideployment.qmlDir:/usr/lib/qt/qml
+}
+
+package() {
+  cd fluid-$pkgver
+  qbs install -d build --no-build -v --install-root "$pkgdir" profile:qt5
+}