[arch-commits] Commit in haskell-lens/repos (2 files)

[Felix Yan]

    Date: Thursday, May 2, 2019 @ 22:57:40
  Author: felixonmars
Revision: 457941

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lens/repos/community-staging-x86_64/
  haskell-lens/repos/community-staging-x86_64/PKGBUILD
    (from rev 457940, haskell-lens/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-lens/repos/community-staging-x86_64/PKGBUILD (from rev 457940, haskell-lens/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-02 22:57:40 UTC (rev 457941)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=lens
+pkgname=haskell-lens
+pkgver=4.17
+pkgrel=42
+pkgdesc="Lenses, Folds and Traversals"
+url="https://github.com/ekmett/lens/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-bifunctors' 'haskell-call-stack' 'haskell-comonad'
+         'haskell-contravariant' 'haskell-distributive' 'haskell-exceptions' 'haskell-free'
+         'haskell-hashable' 'haskell-kan-extensions' 'haskell-parallel' 'haskell-profunctors'
+         'haskell-reflection' 'haskell-semigroupoids' 'haskell-tagged' 'haskell-th-abstraction'
+         'haskell-transformers-compat' 'haskell-unordered-containers' 'haskell-vector' 'haskell-void')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b17e715fd78a427e36fd34cf1b78a66bb620fc481798fe0e3a422df684b472591ac3c6256c2fc391630e7ec09f1d5e9dccc76d72783e4f24bb0687d35266cf67')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-j -ftrustworthy -f-safe -ftest-templates -ftest-properties -ftest-hunit \
+            -ftest-doctests -f-dump-splices -f-old-inline-pragmas -finlining \
+            -f-benchmark-uniplate
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}