[arch-commits] Commit in haskell-pandoc-types/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri May 3 00:07:17 UTC 2019


    Date: Friday, May 3, 2019 @ 00:07:17
  Author: felixonmars
Revision: 458033

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-pandoc-types/repos/community-staging-x86_64/
  haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD
    (from rev 458032, haskell-pandoc-types/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD (from rev 458032, haskell-pandoc-types/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-03 00:07:17 UTC (rev 458033)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=pandoc-types
+pkgname=haskell-pandoc-types
+pkgver=1.17.5.4
+pkgrel=24
+pkgdesc="Types for representing a structured document"
+url="http://johnmacfarlane.net/pandoc"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-quickcheck' 'haskell-syb')
+makedepends=('ghc' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2' 'haskell-hunit' 'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b70dee15e80a91276b04d883f878ca67fdf76195d775f92dc5bbe80c941834fbf067804ea6afa0b79cfc886e4f741d68a161318ab6afb968f159ccbe04a85ce1')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list