[arch-commits] Commit in haskell-monad-par/repos (2 files)

[Felix Yan]

    Date: Friday, May 3, 2019 @ 04:03:38
  Author: felixonmars
Revision: 458170

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monad-par/repos/community-staging-x86_64/
  haskell-monad-par/repos/community-staging-x86_64/PKGBUILD
    (from rev 458169, haskell-monad-par/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-monad-par/repos/community-staging-x86_64/PKGBUILD (from rev 458169, haskell-monad-par/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-03 04:03:38 UTC (rev 458170)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=monad-par
+pkgname=haskell-monad-par
+pkgver=0.3.4.8
+pkgrel=37
+pkgdesc="A library for parallel programming based on a monad"
+url="https://github.com/simonmar/monad-par"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-abstract-deque" "haskell-abstract-par" "haskell-monad-par-extras"
+         "haskell-mwc-random" "haskell-parallel")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6d2f6f571a3eef804e69ca892cf865bb169863d4fa97cad94cfb740925861b827fef14595c2edf235a8a60babdb854eecb87ff09bb798a6912edb7c3c6fe7027')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-newgeneric -f-chaselev
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}