[arch-commits] Commit in haskell-mono-traversable/repos (2 files)

[Felix Yan]

    Date: Friday, May 3, 2019 @ 04:05:09
  Author: felixonmars
Revision: 458172

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-mono-traversable/repos/community-staging-x86_64/
  haskell-mono-traversable/repos/community-staging-x86_64/PKGBUILD
    (from rev 458171, haskell-mono-traversable/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-mono-traversable/repos/community-staging-x86_64/PKGBUILD (from rev 458171, haskell-mono-traversable/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-03 04:05:09 UTC (rev 458172)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=mono-traversable
+pkgname=haskell-mono-traversable
+pkgver=1.0.11.0
+pkgrel=12
+pkgdesc="Type classes for mapping, folding, and traversing monomorphic containers"
+url="https://github.com/snoyberg/mono-traversable"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hashable' 'haskell-split' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-vector-algorithms')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-foldl' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('2be2ed59bd90140cfff5247ce8fb2a4ba1356e471af51b3507fe3cfa1db59a008b71312ddbd5a9e4faeda18305f3117bed1edd1a3eeeeb5fbbca578cce9f2135')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}