[arch-commits] Commit in haskell-websockets/repos (2 files)

[Felix Yan]

    Date: Friday, May 3, 2019 @ 05:33:22
  Author: felixonmars
Revision: 458266

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-websockets/repos/community-staging-x86_64/
  haskell-websockets/repos/community-staging-x86_64/PKGBUILD
    (from rev 458265, haskell-websockets/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-websockets/repos/community-staging-x86_64/PKGBUILD (from rev 458265, haskell-websockets/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-03 05:33:22 UTC (rev 458266)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=websockets
+pkgname=haskell-websockets
+pkgver=0.12.5.3
+pkgrel=11
+pkgdesc="A sensible and clean way to write WebSocket-capable servers in Haskell."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base64-bytestring' 'haskell-case-insensitive'
+         'haskell-entropy' 'haskell-network' 'haskell-random' 'haskell-sha'
+         'haskell-streaming-commons')
+makedepends=('ghc' 'haskell-hunit' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('590df3017f06f11ee17295655280fb95eb6eebb1997cf15ea06ddca9095a569b30e53ded4c111c53347ad5707f338de050a59281455bf120c8554ecc521d8f20')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/bytestring-builder/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-Example
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # Tests hang: https://github.com/jaspervdj/websockets/issues/180
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENCE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENCE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENCE"
+}