[arch-commits] Commit in pyenv/repos (community-any community-any/PKGBUILD)

[David Runge]

    Date: Friday, May 3, 2019 @ 23:32:15
  Author: dvzrv
Revision: 458790

archrelease: copy trunk to community-any

Added:
  pyenv/repos/community-any/
  pyenv/repos/community-any/PKGBUILD
    (from rev 458789, pyenv/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: pyenv/repos/community-any/PKGBUILD (from rev 458789, pyenv/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2019-05-03 23:32:15 UTC (rev 458790)
@@ -0,0 +1,58 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+
+pkgname=pyenv
+pkgver=1.2.11
+pkgrel=2
+pkgdesc="Easily switch between multiple versions of Python"
+arch=('any')
+url="https://github.com/pyenv/pyenv"
+license=('MIT')
+depends=('bash')
+optdepends=('git: installing development versions')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
+sha512sums=('318ca47912b3d50db6298a3e4c881ccdbde038d698e01eb6cf84d1aa377293494951823d3cc764f59a008d0b3d6293d1abf01b1385874ef7f668f42224271b7a')
+
+package() {
+  cd "$pkgname-$pkgver"
+  # application
+  install -vDm 755 libexec/* -t "${pkgdir}/usr/share/${pkgname}/libexec"
+  install -vdm 755 "${pkgdir}/usr/bin"
+  ln -sv "/usr/share/${pkgname}/libexec/${pkgname}" \
+    "${pkgdir}/usr/bin/${pkgname}"
+  # application hooks
+  install -vDm 755 pyenv.d/exec/pip-rehash/* \
+    -t "${pkgdir}/usr/share/${pkgname}/pyenv.d/exec/pip-rehash"
+  install -vDm 644 pyenv.d/exec/*.bash \
+    -t "${pkgdir}/usr/share/${pkgname}/pyenv.d/exec/"
+  install -vDm 644 pyenv.d/rehash/*.bash \
+    -t "${pkgdir}/usr/share/${pkgname}/pyenv.d/rehash"
+  install -vDm 644 pyenv.d/rehash/conda.d/* \
+    -t "${pkgdir}/usr/share/${pkgname}/pyenv.d/rehash/conda.d"
+  install -vDm 644 pyenv.d/rehash/source.d/* \
+    -t "${pkgdir}/usr/share/${pkgname}/pyenv.d/rehash/source.d"
+  # plugin
+  install -vDm 755 plugins/python-build/bin/* \
+    -t "${pkgdir}/usr/share/${pkgname}/plugins/python-build/bin"
+  for bin in {${pkgname}-{install,uninstall},python-build}; do
+    ln -sv "/usr/share/${pkgname}/plugins/python-build/bin/${bin}" \
+      "${pkgdir}/usr/bin/${bin}"
+  done
+  cp -av plugins/python-build/share \
+    "${pkgdir}/usr/share/${pkgname}/plugins/python-build"
+  # licenses
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 plugins/python-build/LICENSE \
+    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.python-build"
+  # shell completion
+  install -vDm 644 completions/*.fish \
+    -t "${pkgdir}/usr/share/fish/completions/"
+  install -vDm 644 completions/${pkgname}.bash \
+    "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
+  install -vDm 644 completions/${pkgname}.zsh \
+    "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
+  # docs
+  install -vDm 644 {CHANGELOG,COMMANDS,README}.md \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 plugins/python-build/README.md \
+    "${pkgdir}/usr/share/doc/${pkgname}/README-python-build.md"
+}