[arch-commits] Commit in haskell-rebase/repos (2 files)

[Felix Yan]

    Date: Saturday, May 4, 2019 @ 15:48:36
  Author: felixonmars
Revision: 458956

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-rebase/repos/community-staging-x86_64/
  haskell-rebase/repos/community-staging-x86_64/PKGBUILD
    (from rev 458955, haskell-rebase/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-rebase/repos/community-staging-x86_64/PKGBUILD (from rev 458955, haskell-rebase/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-04 15:48:36 UTC (rev 458956)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=rebase
+pkgname=haskell-rebase
+pkgver=1.3.1
+pkgrel=8
+pkgdesc='A more progressive alternative to the "base" package'
+url="https://github.com/nikita-volkov/rebase"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hashable' 'haskell-vector' 'haskell-unordered-containers'
+         'haskell-scientific' 'haskell-uuid' 'haskell-dlist' 'haskell-void'
+         'haskell-bifunctors' 'haskell-profunctors' 'haskell-contravariant'
+         'haskell-contravariant-extras' 'haskell-semigroupoids' 'haskell-either'
+         'haskell-base-prelude')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7f639277a5069a3a77f53635fef73259a3549c1bda410de2936a7e499858701c3fd0b1e3dd743a790c566704e6724117209b2917debceef3c163a13c88041ec2')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -e '/fail/d' -e '/semigroups/d' -i $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}