[arch-commits] Commit in pandoc-crossref/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon May 6 07:31:10 UTC 2019


    Date: Monday, May 6, 2019 @ 07:31:10
  Author: felixonmars
Revision: 460487

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-crossref/repos/community-staging-x86_64/
  pandoc-crossref/repos/community-staging-x86_64/PKGBUILD
    (from rev 460486, pandoc-crossref/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: pandoc-crossref/repos/community-staging-x86_64/PKGBUILD (from rev 460486, pandoc-crossref/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-06 07:31:10 UTC (rev 460487)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-crossref
+pkgver=0.3.4.0
+pkgrel=89
+pkgdesc="Pandoc filter for cross-references"
+url="https://hackage.haskell.org/package/${pkgname}"
+license=("GPL2")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-data-default' 'haskell-data-accessor' 'haskell-data-accessor-template'
+         'haskell-data-accessor-transformers' 'haskell-gitrev' 'haskell-open-browser'
+         'haskell-optparse-applicative' 'pandoc' 'haskell-pandoc-types' 'haskell-roman-numerals'
+         'haskell-syb' 'haskell-utility-ht')
+makedepends=('ghc' 'haskell-hspec')
+conflicts=('haskell-pandoc-crossref')
+replaces=('haskell-pandoc-crossref')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lierdakil/pandoc-crossref/archive/v$pkgver.tar.gz")
+sha512sums=('d3a666880f0cad0ef7c1e784f2d52f9bb8bfde9e6be6de04c8f094e2a87e99a740f97951c5ffd74b2a1b001e8a977bc9dd3e28be84c3442d3447beadd879e82c')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i 's/< *2.5/<3/' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+	    -f-enable_flaky_tests
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list