[arch-commits] Commit in haskell-profunctors/repos (2 files)

[Felix Yan]

    Date: Monday, May 6, 2019 @ 11:40:31
  Author: felixonmars
Revision: 460715

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-profunctors/repos/community-staging-x86_64/
  haskell-profunctors/repos/community-staging-x86_64/PKGBUILD
    (from rev 460714, haskell-profunctors/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-profunctors/repos/community-staging-x86_64/PKGBUILD (from rev 460714, haskell-profunctors/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-06 11:40:31 UTC (rev 460715)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=profunctors
+pkgname=haskell-profunctors
+pkgver=5.3
+pkgrel=32
+pkgdesc="Profunctors"
+url="https://github.com/ekmett/profunctors/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-bifunctors' 'haskell-comonad'
+         'haskell-contravariant' 'haskell-distributive' 'haskell-tagged')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a4b5d386aec89b9ede94f0277ea29453435429e27993f9add315b1bba478a214ebb55ece68f74f68ca91dd3e65a1e5c1cc1829bdad81dbf643dfd97029473162')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}