[arch-commits] Commit in haskell-crypto-pubkey-types/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon May 6 15:06:56 UTC 2019


    Date: Monday, May 6, 2019 @ 15:06:56
  Author: felixonmars
Revision: 461027

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-crypto-pubkey-types/repos/community-staging-x86_64/
  haskell-crypto-pubkey-types/repos/community-staging-x86_64/PKGBUILD
    (from rev 461026, haskell-crypto-pubkey-types/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: haskell-crypto-pubkey-types/repos/community-staging-x86_64/PKGBUILD (from rev 461026, haskell-crypto-pubkey-types/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-06 15:06:56 UTC (rev 461027)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=crypto-pubkey-types
+pkgname=haskell-crypto-pubkey-types
+pkgver=0.4.3
+pkgrel=88
+pkgdesc="Generic cryptography Public keys algorithm types"
+url="https://github.com/vincenthz/hs-crypto-pubkey-types"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-asn1-encoding' 'haskell-asn1-types')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('08e6b74ded0decaaf87b4b9ec15af2e8bbeb7095701b5e2062b570af1ecb3d25eb706d6bd91795acfaaf7d09d0e9040359736a0a06a1bc593ef0d8aaf3e374d6')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list