[arch-commits] Commit in haskell-http-conduit/repos (2 files)

[Felix Yan]

    Date: Monday, May 6, 2019 @ 18:09:18
  Author: felixonmars
Revision: 461323

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-conduit/repos/community-staging-x86_64/
  haskell-http-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 461322, haskell-http-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-http-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 461322, haskell-http-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-06 18:09:18 UTC (rev 461323)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-conduit
+pkgname=haskell-http-conduit
+pkgver=2.3.7
+pkgrel=18
+pkgdesc="HTTP client package with conduit interface and HTTPS support"
+url="http://www.yesodweb.com/book/http-conduit"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-http-client' 'haskell-http-client-tls' 'haskell-http-types' 'haskell-resourcet'
+         'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-blaze-builder' 'haskell-case-insensitive' 'haskell-connection'
+             'haskell-cookie' 'haskell-data-default-class' 'haskell-hunit' 'haskell-hspec'
+             'haskell-lifted-base' 'haskell-network' 'haskell-streaming-commons' 'haskell-temporary'
+             'haskell-unliftio' 'haskell-utf8-string' 'haskell-wai' 'haskell-wai-conduit'
+             'haskell-warp' 'haskell-warp-tls')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('55082ab933ca6ead2e03cbc48acd081037faaee3f5ac3207438e93b3dbdbc902ed1b7ea51344383b833718b836180887b3b7c6096c9e0455a20e01d8654bb635')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}