[arch-commits] Commit in haskell-swagger2/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue May 7 13:37:40 UTC 2019


    Date: Tuesday, May 7, 2019 @ 13:37:39
  Author: felixonmars
Revision: 462059

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-swagger2/repos/community-staging-x86_64/
  haskell-swagger2/repos/community-staging-x86_64/PKGBUILD
    (from rev 462058, haskell-swagger2/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-swagger2/repos/community-staging-x86_64/PKGBUILD (from rev 462058, haskell-swagger2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-07 13:37:39 UTC (rev 462059)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=swagger2
+pkgname=haskell-swagger2
+pkgver=2.3.1.1
+pkgrel=24
+pkgdesc="Swagger 2.0 data model"
+url="https://github.com/GetShopTV/swagger2"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base-compat-batteries' 'haskell-cookie'
+         'haskell-hashable' 'haskell-generics-sop' 'haskell-http-media'
+         'haskell-insert-ordered-containers' 'haskell-lens' 'haskell-network' 'haskell-quickcheck'
+         'haskell-scientific' 'haskell-transformers-compat' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-uuid-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-quickcheck-instances'
+             'haskell-hspec-discover' 'haskell-doctest' 'haskell-cabal-doctest' 'haskell-glob'
+             'haskell-utf8-string')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('1834e75cc6c8ff8287605e93d2b4d665b7d8de7e7e00f6537d25e0f54934c85e5431e5f2f1beb5264382c4b81f5ed19cc2b7af1f9323ebee9502e19d73d49fc1')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list