[arch-commits] Commit in haskell-lens-aeson/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 7, 2019 @ 15:36:16
  Author: felixonmars
Revision: 462274

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lens-aeson/repos/community-staging-x86_64/
  haskell-lens-aeson/repos/community-staging-x86_64/PKGBUILD
    (from rev 462273, haskell-lens-aeson/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-lens-aeson/repos/community-staging-x86_64/PKGBUILD (from rev 462273, haskell-lens-aeson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-07 15:36:16 UTC (rev 462274)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=lens-aeson
+pkgname=haskell-lens-aeson
+pkgver=1.0.2
+pkgrel=138
+pkgdesc="Law-abiding lenses for aeson"
+url="http://github.com/lens/lens-aeson/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-lens' 'haskell-scientific'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('db13c9126b41fd1b3b2e66c72e069ef07722c4e125a128eca2592bf2c68b7e550c10a0d35795616c0e66ed6c70bbe3b188e9baba19913bba41b5d44900b71013')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/<.*1.3/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-test-doctests
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}