[arch-commits] Commit in haskell-text-builder/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 7, 2019 @ 16:11:59
  Author: felixonmars
Revision: 462330

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-text-builder/repos/community-staging-x86_64/
  haskell-text-builder/repos/community-staging-x86_64/PKGBUILD
    (from rev 462329, haskell-text-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-text-builder/repos/community-staging-x86_64/PKGBUILD (from rev 462329, haskell-text-builder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-07 16:11:59 UTC (rev 462330)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=text-builder
+pkgname=haskell-text-builder
+pkgver=0.6.5
+pkgrel=19
+pkgdesc="An efficient strict text builder"
+url="https://github.com/nikita-volkov/text-builder"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude' 'haskell-deferred-folds')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-rerebase'
+             'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('20039f281109aa6bb9533054e8799e79a370235e2de901a9ddb7b49534134e0c13c46179054d0801dd9148130bcad29a75ec83a6d7db8dc786774b2390247325')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}