[arch-commits] Commit in python-pluggy/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 8, 2019 @ 08:23:34
  Author: felixonmars
Revision: 462712

archrelease: copy trunk to community-testing-any

Added:
  python-pluggy/repos/community-testing-any/
  python-pluggy/repos/community-testing-any/PKGBUILD
    (from rev 462711, python-pluggy/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-pluggy/repos/community-testing-any/PKGBUILD (from rev 462711, python-pluggy/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2019-05-08 08:23:34 UTC (rev 462712)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pluggy
+pkgname=(python-pluggy python2-pluggy)
+pkgver=0.11.0
+pkgrel=1
+pkgdesc="Plugin and hook calling mechanisms for python"
+arch=('any')
+url="https://www.pluggypayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools-scm' 'python2-setuptools-scm')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/pluggy/archive/$pkgver.tar.gz")
+sha512sums=('e63327ce02fe0b88ceb169c5df787fcf10d338069b18154219c2541635eb6653b33e7a982bf265b94e5b2c9bc98d5960e0da354a59f6a6287cfe009c6a1f8eb1')
+
+prepare() {
+  cp -a pluggy-$pkgver{,-py2}
+
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+}
+
+build() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-pluggy() {
+  depends=('python')
+
+  cd pluggy-$pkgver
+  python setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pluggy() {
+  depends=('python2')
+
+  cd pluggy-$pkgver-py2
+  python2 setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}