[arch-commits] Commit in haskell-yesod-test/repos (2 files)

[Felix Yan]

    Date: Thursday, May 9, 2019 @ 12:59:09
  Author: felixonmars
Revision: 464522

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-test/repos/community-staging-x86_64/
  haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 464521, haskell-yesod-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD (from rev 464521, haskell-yesod-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-09 12:59:09 UTC (rev 464522)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=yesod-test
+pkgname=haskell-yesod-test
+pkgver=1.6.6.1
+pkgrel=9
+pkgdesc="Integration testing for WAI/Yesod Applications"
+url="http://www.yesodweb.com"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hunit' 'haskell-attoparsec' 'haskell-blaze-builder'
+         'haskell-blaze-html' 'haskell-case-insensitive' 'haskell-conduit'
+         'haskell-cookie' 'haskell-hspec-core' 'haskell-html-conduit' 'haskell-http-types'
+         'haskell-network' 'haskell-pretty-show' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-xml-conduit' 'haskell-xml-types' 'haskell-yesod-core')
+makedepends=('ghc' 'haskell-yesod-form' 'haskell-hspec' 'haskell-unliftio')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('833ae785c82ec2cbc34c386fb7678e20cdb905c3eaee2698532e8f09167fac92b5af84b25557f548406184852156e4e22f9f12a86c9a3306cbb23145a4af1cba')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}